Médycs – Incidence : Poids foetal customisé

@@_poidshabituel      :=  {C121:Poids habituel (kg)}
 @@_termeEchoSA        :=  {C1055:Terme corrigé en SA}
 @@_taillemere         :=  {C1191:Taille mère  (cm)}
 @@_nombreaccouchement :=  {C555:Nombre d'accouchements}
 @@_estimpoidsfoetal   :=  {C1818:Estimation du poids foetal (gr)}

@@_SEXE := SI (
 (
 SELECTION({C1551@:Sexe foetal (qcm)};1) ||
 SELECTION({C1551@:Sexe foetal (qcm)};4)
 ) ;
 1 ;
 2)

/* ------  fin définitions des questions ----------- */

@@_semdecimale :=  FORMAT(((STXT({V:_termeEchoSA};0;2)*7)+(STXT({V:_termeEchoSA};4;1))/7);%.%%)

/*------------- EGO --------------*/

@@_wt     := ({V:_poidshabituel}-63,5)
 @@_wtEGO  := FORMAT(({V:_wt}*6,34)+(({V:_wt}^2)*-0,08)+(({V:_wt}^3)*0,0004);0.%)
 @@_ht     := ({V:_taillemere} - 164,5)
 @@_htEGO  := FORMAT({V:_ht}*7,7;0.%%)
 @@_sexEGO := SI({V:_sexe}=1;143,8;0)
 @@_parEGO := SI(({V:_nombreaccouchement} > 3);171,5;REF({V:_nombreaccouchement};0;0;1;114,7;2;117,5;3;135,4))
 @@_TOW    := (3343,3+{V:_wtEGO}+{V:_htEGO}+{V:_sexEGO}+{V:_parEGO})
 @@_perc50 := (299,508404835621-
 (31,8815969178743*{V:_semdecimale})+
 (1,09473518354711*({V:_semdecimale}^2))-
 (0,0105627091346906*({V:_semdecimale}^3)))

@@_50perc := FORMAT(({V:_perc50}/100)*{V:_TOW};%%%%)
 @@_perc3  := (0,7776*{V:_perc50})
 @@_3perc  := FORMAT(({V:_perc3}/100)*{V:_TOW};%%%%)
 @@_perc5  := (0,804*{V:_perc50})
 @@_5perc  := FORMAT(({V:_perc5}/100)*{V:_TOW};%%%%)
 @@_perc10 := (0,847*{V:_perc50})
 @@_10perc := FORMAT(({V:_perc10}/100)*{V:_TOW};%%%%)
 @@_perc90 := (1,153*{V:_perc50})
 @@_90perc := FORMAT(({V:_perc90}/100)*{V:_TOW};%%%%)
 @@_perc95 := (1,196*{V:_perc50})
 @@_95perc := FORMAT(({V:_perc95}/100)*{V:_TOW};%%%%)
 @@_perc97 := (1,224*{V:_perc50})
 @@_97perc := FORMAT(({V:_perc97}/100)*{V:_TOW};%%%%)
 @@_TOW-SA := FORMAT({V:_TOW}*
 (/*frac = */(298,8-(31,85*{V:_semdecimale})+(1,094*({V:_semdecimale}^2))-
 (0,01055*({V:_semdecimale}^3)))/100/* Fin frac */);"%%%%")

@@_dsEGO := FORMAT((0,127*{V:_TOW-SA});"%%%%")
 @@_zsEGO := FORMAT((({V:_estimpoidsfoetal} - {V:_TOW-SA})/{V:_dsEGO});0.%%)

/*------------- RESULTAT --------------*/

@@_ :=
 SI({V:_estimpoidsfoetal}<{V:_3perc};"< 3°p";
 SI({V:_estimpoidsfoetal}<{V:_5perc};"3°-5°p";
 SI({V:_estimpoidsfoetal}<{V:_10perc};"5°-10°p";
 SI({V:_estimpoidsfoetal}<{V:_50perc};"10°-50°p";
 SI({V:_estimpoidsfoetal}<{V:_90perc};"50°-90°p";
 SI({V:_estimpoidsfoetal}<{V:_95perc};"90°-95°p";
 SI({V:_estimpoidsfoetal}<{V:_97perc};"95°-97°p";
 ">97°p")))))))

/* D'après : Ego A, Subtil D, Grange G, Thiebaugeorges O, Senat MV, Vayssiere C, et al. Customized versus population-based
 birth weight standards for identifying growth restricted infants: a French multicenter study.
 Am J Obstet Gynecol 2006; 194: 1042-1049.*/